JAcousticsToolkit.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                               Toolkit for acoustics scripts.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

if do_usage $*; then
    usage "source $script"\
          "\nToolkit for acoustics scripts."
fi


#
# Method to add tripod data from given file into associative array. 
#
# \param  1      file name
# \param  2      associative array
#
function get_tripods+()
{
    set_local_variable __FILE__        $1
    set_local_variable __ARRAY__       $2

    while read __line__; do

        if [[ -n "$__line__" && "$__line__" != \#* ]]; then

            echo $__line__ | read __id__ __x__ __y__ __z__

            eval ${__ARRAY__}\[${__id__}\]=\"$__x__ $__y__ $__z__\"
        fi

    done < $__FILE__
}


#
# Method to write tripod data from given file into associative array. 
#
# \param  1      file name
# \param  2      associative array
#
function get_tripods()
{
    eval $2=\(\)

    get_tripods+ $1 $2
}


#
# Method to add transmitter data from given file into associative array. 
#
# \param  1      file name
# \param  2      associative array
#
function get_transmitters+()
{
    set_local_variable __FILE__        $1
    set_local_variable __ARRAY__       $2

    while read __line__; do

        if [[ -n "$__line__" && "$__line__" != \#* ]]; then

            echo $__line__ | read __id__ __string__ __floor__ __x__ __y__ __z__

            eval ${__ARRAY__}\[${__id__}\]=\"$__x__ $__y__ $__z__\"
        fi

    done < $__FILE__
}


#
# Method to write transmitter data from given file into associative array. 
#
# \param  1      file name
# \param  2      associative array
#
function get_transmitters()
{
    eval $2=\(\)

    get_transmitters+ $1 $2
}


#
# Method to print string numbers of strings with with transmitter.
#
# \param  1      file name
# \return        string numbers
#
function get_strings_with_transmitter()
{
    set_local_variable __FILE__        $1

    while read __line__; do

        if [[ -n "$__line__" && "$__line__" != \#* ]]; then

            echo $__line__ | read __id__ __string__ __floor__ __x__ __y__ __z__

            echo -n " $__string__"
        fi

    done < $__FILE__

    echo
}


#
# Method to print string numbers of strings with with hydrophone.
#
# \param  1      file name
# \return        string numbers
#
function get_strings_with_hydrophone()
{
    set_local_variable __FILE__        $1

    while read __line__; do

        if [[ -n "$__line__" && "$__line__" != \#* ]]; then

            echo $__line__ | read __string__ __floor__ __x__ __y__ __z__

            echo -n " $__string__"
        fi

    done < $__FILE__

    echo
}


#
#  Method to write waveform data from given file into associative array.
#
# \param  1      file name
# \param  2      associative array
#
function get_waveforms()
{
    set_local_variable __FILE__        $1
    set_local_variable __ARRAY__       $2

    while read __line__; do

        if [[ -n "$__line__" && "$__line__" != \#* ]]; then

            echo $__line__ | read __id__ __m__

            eval ${__ARRAY__}\[${__id__}\]=\"$__m__\"
        fi

    done < $__FILE__
}