JSquid.sh

Go to the documentation of this file.

#!/bin/zsh

source $JPP_DIR/setenv.sh $JPP_DIR

zmodload zsh/mathfunc

set_variable   DEBUG        2
set_variable   WORKDIR      ${TMPDIR:-/tmp}/
set_variable:  FORMAT       GRAPHICS_FORMAT        gif
set_variable+  BATCH        GRAPHICS_BATCH         -B

if do_usage $*; then
    usage "$script <detector file> <input file>"
fi

if (( $# != 2 )); then
    fatal "Wrong number of arguments."
fi

set_variable DETECTOR    $argv[1]
set_variable INPUT_FILE  $argv[2]

eval `JPrintDetector -a $DETECTOR -O SUMMARY`

JPrintDAQHeader -f $INPUT_FILE  |  read -A DAQ_HEADER

set_variable  DETECTOR_ID    ${DAQ_HEADER[1]}
set_variable  RUN            ${DAQ_HEADER[2]}

if ( ! reuse_file $WORKDIR/trigger_processor.root ); then

    JTriggerProcessor \
        -a $DETECTOR                                      \
        -f $INPUT_FILE                                    \
        -C JDAQTimesliceSN                                \
        -@ "trigger3DMuon.enabled         =  1"           \
        -@ "trigger3DMuon.numberOfHits    =  3"           \
        -@ "trigger3DMuon.numberOfModules =  3"           \
        -@ "trigger3DMuon.gridAngle_deg   = 10"           \
        -@ "trigger3DMuon.TMaxExtra_ns    = 500.0e3"      \
        -@ "TMaxEvent_ns    = 500.0e3"                    \
        -@ "TMaxLocal_ns    = 20.0"                       \
        -@ "L2.numberOfHits = 4"                          \
        -@ "L2.TMaxLocal_ns = 20.0"                       \
        -@ "L2.ctMin        = 0.0"                        \
        -o $WORKDIR/trigger_processor.root                \
        -d $DEBUG
fi

$JPP_DIR/examples/JDataQuality/JSquid \
    -a $DETECTOR                                          \
    -f $WORKDIR/trigger_processor.root                    \
    -o $WORKDIR/squid.root                                \
    -d $DEBUG

for STRING in $STRINGS[*]; do

    JPlot1D \
        -f $WORKDIR/squid.root:"^[ ]*${STRING}"           \
        -\> "#Deltat [ns]"                                \
        -\^ "number of hits [a.u.]"                       \
        -T "$RUN"                                         \
        -N "X 505"                                        \
        -L TL                                             \
        -o $WORKDIR/T${(l:4::0::0:)STRING}.gif            $BATCH
done

typeset -i NX
typeset -i NY

let "NY = sqrt(${#STRINGS}) * 0.75"
let "NX = (${#STRINGS} + $NY - 1)/ $NY"

montage \
    -tile ${NX}x${NY}                                     \
    -geometry +0+0                                        \
    $WORKDIR/T[0-9][0-9][0-9][0-9].$FORMAT                \
    ${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}.$FORMAT >& /dev/null