JCalibratePMT.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author rgruiz, mdejong
#
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                         Script to run complete PMT calibration.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  WORKDIR           CALIBRATION_WORKDIR           ./
set_variable:  DEBUG             CALIBRATION_DEBUG             2
set_variable+  OPTION            CALIBRATION_OPTION            -A

if do_usage $*; then
    usage "$script <detector_file> (input file)+ <PMT parameters file>"
fi

if (( $# < 3 )); then
    fatal "Wrong number of arguments."
fi 

set_variable   DETECTOR          $argv[1]
set_array      INPUT_FILES       $argv[2,-2]
set_variable   PMT_FILE          $argv[-1]

if [[ ! -d $WORKDIR ]]; then     
    mkdir -p $WORKDIR
fi

JCookie.sh

eval `JPrintDetector -a $DETECTOR -O IDENTIFIER`

debug "$DETECTOR $DETECTOR_ID"

if [[ "$DETECTOR_ID" != [1-9][0-9]* ]]; then
    fatal "Invalid detector identifier \"$DETECTOR_ID\"."
fi

# evaluate inputs

set_variable   RUNSETUPID
typeset -a     RANGE

RANGE[1]=99999999
RANGE[2]=0

for INPUT_FILE in $INPUT_FILES[*]; do

    JPrintDAQHeader  -f $INPUT_FILE  |  read ID RUN FRAME_INDEX UTC    

    if (( $DETECTOR_ID != $ID )); then
        fatal "Inconsistent detector identifier $DETECTOR_ID != $ID."
    fi

    JRuns  -D $DETECTOR_ID  -@ "RUN = $RUN"  -F RUNSETUPID  |  read SETUP

    debug "Run $RUN -> $SETUP."

    if (( $RUN < $RANGE[1] )); then; RANGE[1]=$RUN; fi
    if (( $RUN > $RANGE[2] )); then; RANGE[2]=$RUN; fi

    if [[ -z "$SETUP" ]]; then
        fatal "Missing setup identifier for run $RUN."
    fi
    if [[ -n "$RUNSETUPID" && $RUNSETUPID != $SETUP ]]; then
        fatal "Inconsistent run setup identifiers $RUNSETUPID != $SETUP."
    fi

    set_variable   RUNSETUPID  $SETUP
done


# data selection

for DAQ_TIMESLICE in JDAQTimesliceL1 JDAQTimeslice; do

    JPrintTree -f${^INPUT_FILES} |& eval awk \'\{ if \( \$2 \~ \"${DAQ_TIMESLICE}$\" \) \{ printf \" %d\", \$3 \}\}\'  | read -A VALUES

    if [[ -n "$VALUES" ]] && (( ${#VALUES} == ${#INPUT_FILES} )); then
        break
    fi
done

if [[ -z "$VALUES" ]] || (( ${#VALUES} != ${#INPUT_FILES} )); then
    fatal "No valid data in input file(s)."
fi


# PMT threshold

JPMTThreshold \
    -D $DETECTOR_ID        \
    -r $RANGE[1]           \
    -P $PMT_FILE           \
    --!


# PMT TTS function

JPMTTTS \
    -D $DETECTOR_ID        \
    -P $PMT_FILE           \
    --!


# PMT gain and gain spread

set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_calibratetot.root

JCalibrateToT \
    -a $DETECTOR             \
    -f${^INPUT_FILES}        \
    -o $OUTPUT_FILE          \
    -C $DAQ_TIMESLICE        \
    -d $DEBUG --!

CHECK_EXIT_CODE

set_variable  INPUT_FILE   $OUTPUT_FILE
set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_mergetot.root

JMergeCalibrateToT           \
    -f $INPUT_FILE           \
    -o $OUTPUT_FILE          \
    -d $DEBUG --!

CHECK_EXIT_CODE

set_variable  INPUT_FILE   $OUTPUT_FILE
set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_fittot.root

JFitToT                      \
    -a $DETECTOR             \
    -f $INPUT_FILE           \
    -o $OUTPUT_FILE          \
    -P $PMT_FILE             \
    -w                       \
    -d $DEBUG --!


# PMT QE

set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_calibratek40.root

timer_start

JCalibrateK40 \
    -a $DETECTOR             \
    -f${^INPUT_FILES}        \
    -o $OUTPUT_FILE          \
    -C $DAQ_TIMESLICE        \
    -d $DEBUG --!

CHECK_EXIT_CODE

timer_stop
timer_print

set_variable  INPUT_FILE   $OUTPUT_FILE
set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_mergek40.root

JMergeCalibrateK40           \
    -f $INPUT_FILE           \
    -o $OUTPUT_FILE          \
    -d $DEBUG --!

CHECK_EXIT_CODE

set_variable  INPUT_FILE   $OUTPUT_FILE
set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RANGE[1]}-${(l:8::0::0:)RANGE[2]}_fitk40.root

JFitK40                      \
    -a $DETECTOR             \
    -f $INPUT_FILE           \
    -o $OUTPUT_FILE          \
    -P $PMT_FILE             \
    -w                       \
    $OPTION                  \
    -d $DEBUG --!

CHECK_EXIT_CODE