getFile.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
script=${0##*/}

source ${0%${script}}ulib.sh

set_variable:  DEBUG        ARCHIVE_DEBUG       2
set_variable   VERSION      "*"

if do_usage $*; then
    usage "$script  <path>  <detector identifier>  <run>  <type>  [version]  <output file>"\
          "\nUtility script to retrieve file from archive."\
          "\nNote that extension from name of file in archive is taken."
fi

case $# in
    6)  set_variable   VERSION      $argv[5];&
    5)  set_variable   DIR          $argv[1];
        let            ID="         $argv[2]";
        let            RUN="        $argv[3]";
        set_variable   TYPE         $argv[4];
        set_variable   OUTPUT_FILE  $argv[-1];;
    *)  fatal "Wrong number of arguments."
esac

if [[ ! -d $DIR ]]; then
    fatal "Invalid path $argv[1]"
fi

if (( $ID  == 0 )); then
    fatal "Invalid detector identifier $argv[2]"
fi

if (( $RUN == 0 )); then
    fatal "Invalid run $argv[3]"
fi

setopt extendedglob

typeset -Z8 ID

let COUNTER="0"
INPUT_FILE=""

if [[ -d $DIR/$ID/$TYPE ]]; then

    typeset -T BUFFER ARRAY /

    eval ls -1 $DIR/$ID/$TYPE/_${VERSION}/\*/\*/\* 2> /dev/null | while read BUFFER; do

        set_variable  A_ID       ${ARRAY[-6]}
        set_variable  A_TYPE     ${ARRAY[-5]}
        set_variable  A_VERSION  ${ARRAY[-4]#_}
        let           A_MINRUN=" ${ARRAY[-3]}"
        let           A_MAXRUN=" ${ARRAY[-2]}"
        set_variable  A_FILENAME ${ARRAY[-1]}

        let           A_COUNTER="${A_FILENAME:r}"

        if (( $RUN >= $A_MINRUN && $RUN <= $A_MAXRUN )); then
            if (( $A_COUNTER > $COUNTER )); then
                let COUNTER="$A_COUNTER"
                INPUT_FILE=$BUFFER
            fi
        fi
    done
else
    fatal "No archive $DIR/$ID/$TYPE"
fi

if [[ -z $INPUT_FILE ]]; then
    fatal "No corresponding files found in archive $DIR"
fi

OUTPUT_FILE+=.${INPUT_FILE:e}

if [[ -f $OUTPUT_FILE ]]; then
    fatal "File $OUTPUT_FILE already exists."
fi
    
cp -p  $INPUT_FILE  $OUTPUT_FILE

if (( $? == 0 )); then
    notice "Stored archive:$INPUT_FILE to $OUTPUT_FILE"
else
    fatal  "File $INPUT_FILE not retrieved from archive."
fi