JDataQuality.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable:  DEBUG       QAQC_DEBUG            2
set_variable:  WORKDIR     QAQC_WORKDIR          `pwd`
set_variable:  FORMAT      GRAPHICS_FORMAT       gif
set_variable+  BATCH       GRAPHICS_BATCH        -B

if do_usage $*; then
    usage "$script [<detector identifier> <run range>] <QA/QC file>"\
          "\nExample script to produce data quality plots."\
          "\nWhen a detector identifier and run range are specified, data are downloaded from the database"\
          "\nand subsequently stored in the given QA/QC file, unless this file already exists."
fi

case $# in
    0)  fatal "Wrong number of arguments.";;
    3)  set_variable  DETECTOR_ID     $argv[1]
        set_variable  RANGE           $argv[2];&
    1)  set_variable  QUALITY_TXT     $argv[-1];;
esac

set_variable  FILEPREFIX    ${${QUALITY_TXT%%.*}##.*/}
set_variable  QUALITY_ROOT  ${QUALITY_TXT%%.*}.root

if (( $# == 3 )); then

    if ( ! reuse_file $QUALITY_TXT ); then

        JCookie.sh

        JDataQuality \
            -D "$DETECTOR_ID"                                          \
            -R "${RANGE%%-*} ${RANGE##*-}"                             \
            -o  $QUALITY_TXT                                           \
            -d  $DEBUG --!
    else

        echo "Note that the specified detector identifer and runs are discarded."
    fi
fi


JDataQuality \
    -D "$DETECTOR_ID"                                                                        \
    -R "${RANGE%%-*} ${RANGE##*-}"                                                           \
    -f  $QUALITY_TXT                                                                         \
    -Q "livetime_s;                                                        1200     60000"   \
    -Q "(UTCMax_s - UTCMin_s) - livetime_s;                               -100     +100"     \
    -Q "JDAQEvent / livetime_s;                                            0.05     50.0"    \
    -Q "HRV;                                                               0.00     0.2"     \
    -Q "DAQ;                                                               0.95     1.05"    \
    -Q "WR;                                                                0.95     1.05"    \
    -Q "FIFO;                                                              0.00     0.01"    \
    -Q "MEAN_Rate_Hz;                                                      4500    15000"    \
    -Q "RMS_Rate_Hz;                                                       200      5000"    \
    -Q "Acoustics / livetime_s;                                            0.0      100.0"   \
    -Q "AHRS      / livetime_s;                                            0.0      100.0"   \
    -V "(JDAQEvent - JTriggerReprocessor) * 1.0 / (JDAQEvent + 1.0e-10);  -5.0e-3  +5.0e-3"  \
    -V "out_sync;                                                          0        0"       \
    -V "out_usync;                                                         0        0"       \
    -o  $QUALITY_ROOT                                                                        \
    -d  $DEBUG --!

CHECK_EXIT_CODE


JPlot1D \
    -f ${QUALITY_ROOT}:h0                                          \
    -\> "quality"                                                  \
    -\^ "number of runs"                                           \
    -T ""                                                          \
    -o $WORKDIR/${FILEPREFIX}_quality.${FORMAT}                    $BATCH

JPlot1D \
    -f ${QUALITY_ROOT}:h1                                          \
    -\^ "number of runs"                                           \
    -T ""                                                          \
    -o $WORKDIR/${FILEPREFIX}_selection.${FORMAT}                  $BATCH

JPlot1D \
    -w 1200x600                                                    \
    -f ${QUALITY_ROOT}:VETO                                        \
    -\> "run number"                                               \
    -O P                                                           \
    -N "X 505"                                                     \
    -T "VETO"                                                      \
    -L BL                                                          \
    -o $WORKDIR/${FILEPREFIX}_veto.${FORMAT}                       $BATCH

typeset -A BUFFER

BUFFER=(
    \^livetime_s\$                           livetime
    UTC                                      UTC-livetime
    \^JDAQEvent\.\*livetime_s                event-rate
    \^\(JDAQEvent\.\*JTriggerReprocessor\)   event-count
    HRV                                      HRV
    \^DAQ\$                                  DAQ
    WR                                       WR
    FIFO                                     FIFO
    MEAN_Rate_Hz                             PMT-rate-mean
    RMS_Rate_Hz                              PMT-rate-rms
    \^out_sync\$                             out_sync
    \^out_usync\$                            out_usync
    Acoustics                                acoustics
    AHRS                                     AHRS)

for KEY VALUE in ${(@kv)BUFFER}; do

    JPlot1D \
        -w 1200x600                                                    \
        -f ${QUALITY_ROOT}:${KEY}                                      \
        -\> "run number"                                               \
        -O P                                                           \
        -N "X 505"                                                     \
        -T "?"                                                         \
        -o $WORKDIR/${FILEPREFIX}_${VALUE}.${FORMAT}                   $BATCH
done