JTriggerProfiler.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
version=1.0
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                  Utility script to plot JTriggerProcessor CPU requirements.
#
# ------------------------------------------------------------------------------------------


if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi


source $JPP_DIR/setenv.sh $JPP_DIR


set_variable   DEBUG             1                                      
set_variable   WORKDIR           ./                                     
set_variable   DETECTOR          $JPP_DATA/km3net_reference.detx        
set_variable   TRIGGER           $JPP_DATA/trigger_parameters_arca.txt  
set_variable   FRAMETIME_MS      100                                    
set_variable   RATE_L1_HZ        500                                    
set_variable   RECYCLING         5 100e3
set_variable:  FORMAT            GRAPHICS_FORMAT        gif
set_variable+  BATCH             GRAPHICS_BATCH         -B

if do_usage $*; then
    usage "$script [detector file [trigger file [working directory]]]"
fi

case $# in
    3) set_variable  WORKDIR   $3;&
    2) set_variable  TRIGGER   $2;&
    1) set_variable  DETECTOR  $1;;
    0) ;;
    *) fatal "Wrong number of arguments."
esac


set_variable   PIPE         $WORKDIR/pipe.dat
set_variable   CPU_TXT      $WORKDIR/cpu.txt
set_variable   CPU_ROOT     $WORKDIR/cpu.root
set_variable   RATE_TXT     $WORKDIR/rate.txt
set_variable   RATE_ROOT    $WORKDIR/rate.root


echo "Detector: $DETECTOR"
echo "Trigger parameters:"
cat  $TRIGGER


typeset -A SETUPS  # rate -> number of slices

SETUPS[5e3]=100
SETUPS[7e3]=100
SETUPS[9e3]=100
SETUPS[11e3]=100
SETUPS[13e3]=50
SETUPS[15e3]=50
SETUPS[17e3]=50
SETUPS[19e3]=20


for RATE_L0_HZ NUMBER_OF_SLICES in ${(kv)SETUPS}; do

    LOGGER_FILE=$WORKDIR/trigger_${RATE_L0_HZ}.log

    if [[ ! -f $LOGGER_FILE ]]; then
        
        rm -f  $PIPE
        mkfifo $PIPE
        
        echo "Generating random background at ${RATE_L0_HZ} Hz."
        
        nohup JRandomTimesliceWriter \
              -a $DETECTOR                   \
              -o $PIPE                       \
              -B "$RATE_L0_HZ $RATE_L1_HZ"   \
              -n $NUMBER_OF_SLICES           \
              -N "$RECYCLING"                \
              -d $DEBUG > /dev/null 2>&1 &
        
        echo Processing random data.
        
        JTriggerProcessor \
            -a $DETECTOR                     \
            -f $PIPE                         \
            -o "/dev/null"                   \
            -@"`cat $TRIGGER`"               \
            -C JDAQTimesliceL0               \
            -d $DEBUG > $LOGGER_FILE 2>&1

        rm -f  $PIPE
    fi
done


rm -f $CPU_TXT  >& /dev/null
rm -f $RATE_TXT >& /dev/null

for RATE_L0_HZ in ${(k)SETUPS}; do
    
    LOGGER_FILE=$WORKDIR/trigger_${RATE_L0_HZ}.log
    
    let "TOTAL_CPU = 0.0"
    
    for KEY in "Calibration" "L0" "L1" "L2" "Timeslice router" "Trigger" "Trigger router"; do
        
        ELAPSED_TIME=`awk -v key="$KEY" '$0 == key,/CPU/ { if ($3 == "elapsed") print $1 }' $LOGGER_FILE`
        
        let "TOTAL_CPU += $ELAPSED_TIME / $FRAMETIME_MS"
    done

    TRIGGER_RATE_HZ=`awk '/Trigger rate \[Hz\]/ { print $4 }' $LOGGER_FILE`

    echo "$(($RATE_L0_HZ * 1e-3)) $TOTAL_CPU"       >> $CPU_TXT
    echo "$(($RATE_L0_HZ * 1e-3)) $TRIGGER_RATE_HZ" >> $RATE_TXT
done


JGraph \
    -f $CPU_TXT               \
    -o $CPU_ROOT

JPlot1D \
    -f $CPU_ROOT:\.\*         \
    -x "0 20"                 \
    -\> "Rate [kHz]"          \
    -\^ "CPU [cores]"         \
    -T ""                     \
    -o cpu.$FORMAT            $BATCH


JGraph \
    -f $RATE_TXT              \
    -o $RATE_ROOT

JPlot1D \
    -f $RATE_ROOT:\.\*        \
    -x "0 20"                 \
    -\> "Rate [kHz]"          \
    -\^ "Trigger rate [Hz]"   \
    -T ""                     \
    -o rate.$FORMAT           $BATCH