putFile.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
script=${0##*/}

source ${0%${script}}ulib.sh

set_variable:  DEBUG        ARCHIVE_DEBUG       2
set_variable   VERSION      ""

if do_usage $*; then
    usage "$script  <input file>  <path>  <detector identifier>  <minimal run>  <maximal run>  <type>  <version>"\
          "\nUtility script to store file in archive."
fi

case $# in
    7)  set_variable   INPUT_FILE   $argv[1];
        set_variable   DIR          $argv[2];
        let            ID="         $argv[3]";
        let            MINRUN="     $argv[4]";
        let            MAXRUN="     $argv[5]";
        set_variable   TYPE         $argv[6];
        set_variable   VERSION      $argv[7];;
    *)  fatal "Wrong number of arguments."
esac

if [[ ! -d $DIR ]]; then
    fatal "Invalid path $argv[2]"
fi

if [[ ! -f $INPUT_FILE ]]; then
    fatal "File $INPUT_FILE does not exist."
fi

if (( $ID     == 0 )); then
    fatal "Invalid detector identifier $argv[3]"
fi

if (( $MINRUN == 0 )); then
    fatal "Invalid minimal run $argv[4]"
fi

if (( $MAXRUN == 0 )); then
    fatal "Invalid minimal run $argv[5]"
fi

if (( $MINRUN > $MAXRUN )); then
    fatal "Invalid minimal / maximal run $argv[4] / $argv[5]"
fi

if [[ $VERSION == *[^[:alnum:_-]]* ]]; then
    fatal "Invalid version $argv[7] (special characters not allowed)"
fi
    
setopt extendedglob

typeset -Z8 ID
typeset -Z8 MINRUN
typeset -Z8 MAXRUN

let COUNTER="0"

if [[ -d $DIR/$ID/$TYPE ]]; then

    typeset -T BUFFER ARRAY /

    (ls -1 $DIR/$ID/$TYPE/_*/*/*/*) 2> /dev/null | while read BUFFER; do

        set_variable  A_ID       ${ARRAY[-6]}
        set_variable  A_TYPE     ${ARRAY[-5]}
        set_variable  A_VERSION  ${ARRAY[-4]#_}
        let           A_MINRUN=" ${ARRAY[-3]}"
        let           A_MAXRUN=" ${ARRAY[-2]}"
        set_variable  A_FILENAME ${ARRAY[-1]}
        
        let           A_COUNTER="${A_FILENAME:r}"

        if (( $MINRUN <= $A_MAXRUN && $MAXRUN >= $A_MINRUN )); then
            if (( $A_COUNTER > $COUNTER )); then
                let COUNTER="$A_COUNTER"
            fi
        fi
    done
fi

let COUNTER="$COUNTER + 1"

set_variable  OUTPUT_FILE  $DIR/$ID/$TYPE/_${VERSION}/$MINRUN/$MAXRUN/${COUNTER}.${INPUT_FILE:e}

mkdir -p ${OUTPUT_FILE:h}

if (( $? != 0 )); then
    fatal "Path ${OUTPUT_FILE:h} not created."
fi

cp -p  $INPUT_FILE  $OUTPUT_FILE

if (( $? == 0 )); then
    notice "Stored $INPUT_FILE to archive:$OUTPUT_FILE"
else
    fatal  "File $INPUT_FILE not stored in archive."
fi