JEvtReweightGSeaGenParameterScan.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author bjung
#
version=1.0
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                         Utility script to evaluate gSeaGen reweightings
#
# ------------------------------------------------------------------------------------------


if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR
source $JPP_DIR/software/scripts/qlib.sh


set_variable     IFS0                     ${IFS}

set_variable:    DEBUG                    REWEIGHTING_DEBUG                           2

set_variable+    BATCH_PROCESSING         REWEIGHTING_BATCH_PROCESSING                1
set_variable+    BATCH_LOGGING            REWEIGHTING_BATCH_LOGGING                   1
set_variable:    QUEUE_SIZE               REWEIGHTING_QUEUE_SIZE                      3
set_variable:    QUEUE_NAME               REWEIGHTING_QUEUE_NAME                      ${TMPDIR:-/tmp}/queue
set_variable:    JOB_SIZE                 REWEIGHTING_JOB_SIZE                        1

set_variable:    TEST_TYPE1D              REWEIGHTING_TEST_TYPE1D                     0
set_variable:    TEST_TYPE1D_PARAMETERS   REWEIGHTING_TEST_TYPE1D_PARAMETERS          "0.05 UWCHI2/NDF"
set_variable:    TEST_TYPE2D              REWEIGHTING_TEST_TYPE2D                     0
set_variable:    TEST_TYPE2D_PARAMETERS   REWEIGHTING_TEST_TYPE2D_PARAMETERS          "0.05 UWCHI2/NDF"

set_variable:    SCRATCHDIR               REWEIGHTING_SCRATCHDIR                      ${TMPDIR:-/tmp}

set_variable:    N_TRIGGERED_HITS_RANGE   REWEIGHTING_N_TRIGGERED_HITS_RANGE          "0 $((2**31))"
set_variable:    CONTAINMENT_VOLUME       REWEIGHTING_CONTAINMENT_VOLUME              "0.0 0.0 $((2**31)) -$((2**31)) $((2**31))" 
set_variable:    COSTH_RANGE              REWEIGHTING_COSTH_RANGE                     "-1.0 1.0"
set_variable:    ENERGY_RANGE             REWEIGHTING_ENERGY_RANGE                    "0.0 $((2.0**31))"

set_variable:    RECOTYPE                 REWEIGHTING_RECOTYPE                        "track"

set_variable     DEFAULT_OSCPARAMETERS_FILE                                           ${JPP_DATA}/oscillation_parameters_NO.txt
set_variable     OSCPARAMETERS_GRID_FILE                                              ""
set_variable     LIVETIME                                                             $(( 5 * 365.25 * 24. * 3600. )) # Default livetime of 5 years
set_variable     WORKDIR                                                              ${TMPDIR:-/tmp}


if do_usage $*; then
    usage "$script <detector file> <input file>+ <reweighting file> <oscillation probability table> [default oscillation parameter file [oscillation parameter grid file [working directory]]]\n" \
          "Note that if more than one input file is given all optional parameters need to be specified."
fi

case $# in
    8) set_variable WORKDIR                       $8;&
    7) set_variable LIVETIME                      $7;&
    6) set_variable OSCPARAMETERS_GRID_FILE       $6;&    
    5) set_variable DEFAULT_OSCPARAMETERS_FILE    $5;&
    4) set_variable OSCPROBTABLE                  $4;
       set_variable REWEIGHTING_INPUTS_FILE       $3;
       set_array    INPUT_FILES                   $2;
       set_variable DETX_FILE                     $1;;
    *) set_variable DETX_FILE                     ${argv[1]}
       set_array    INPUT_FILES                   ${argv[2,-7]}
       set_variable REWEIGHTING_INPUTS_FILE       ${argv[-6]}
       set_variable OSCPROBTABLE                  ${argv[-5]}
       set_variable DEFAULT_OSCPARAMETERS_FILE    ${argv[-4]}
       set_variable OSCPARAMETERS_GRID_FILE       ${argv[-3]}
       set_variable LIVETIME                      ${argv[-2]}
       set_variable WORKDIR                       ${argv[-1]}
esac


# Recursive function to process parameter files
# 
# \param  prefix                   prefix
# \param  label                    neutrino label
# \param  formula                  reweighting formula
# \param  parameters_file          parameter file
#
process_parameters() {
    
    local prefix=$1
    local labels=$2
    local formula=$3
    local parameters_file=$4

    shift 4

    while read line; do
        
        if [[ ${line:0:1} == \# ]]; then continue; fi

        pars=( $(echo $line | cut -d' ' -f1-) )

        unset parstr
        
        for (( i=1; i<=${#pars}; ++i )); do
            local parstr="${parstr} p$((i-1))=${pars[$i]};"
        done

        local reweighting_input=$(printf "\t%s=\"${formula};${parstr}\"" ${(z)labels})
        
        if (( $# )); then
            process_parameters "${prefix}${reweighting_input}" "$@"
        else
            printf '%b\n'      "${prefix}${reweighting_input}"
        fi
    done < ${parameters_file}
}


# Function to write job identifier to file
#
# \param  output_file    output file
#
write_jobID() {

    local output_file=$1

    if (( ${+BATCH_PROCESSING} )); then

        if [[ -z $EXEC_FILE ]]; then fatal "write_jobID(): Variable EXEC_FILE undefined"; fi

        if ( is_CCNikhef ); then
            local jobid=$(qstat -u $USER -f | grep -B1 "${EXEC_FILE:t:r}.${USER}" | grep -oP "Job Id: [0-9]+" | tail -1 | cut -d' ' -f3)
        else
            local jobid=$(ps | grep "${EXEC_FILE:t:r}" | tail -1 | tr -s ' ' | cut -d' ' -f2)
        fi

        echo ${jobid} >> ${output_file}
    fi
}


# Set neutrino labels

typeset -A NULABELS
set_array  NULABELS \
    -16 "anutau" \
    -14 "anumu"  \
    -12 "anue"   \
     12 "nue"    \
     14 "numu"   \
     16 "nutau"


# Initialise local batch processor

if [[ ${BATCH_PROCESSING} == 1 ]]; then

    if   ( is_CCNikhef ); then

        echo "Submitting reweighting and histogram comparison jobs to nikhef-stbc batch queue: ${QUEUE_NAME}..."

        if [[ ${SCRATCHDIR} == "/tmp" ]]; then
            fatal "Please specify a valid directory for local \'scratch\' files other than \"${TMPDIR:-/tmp}\""
        fi
        
    elif ( is_CCLyon ); then

        fatal "No batch-processing option available yet for CC-Lyon."
        
    else
        
        echo "Submitting reweighting and histogram comparison jobs to local batch queue: ${QUEUE_NAME}..."

        $JPP_DIR/examples/scripts/mkqueue.sh  ${QUEUE_NAME}  ${QUEUE_SIZE}  "start"
    fi
fi


# Retrieve MC files

set_array    MC_MERGE_FILES               $(find ${WORKDIR} -maxdepth 1 -name "*.merge.root")
set_variable MC_MERGE_FILELIST            ${WORKDIR}/merged.files

if (( ${#MC_MERGE_FILES} != 0 )); then

    echo  "----------------------------"    
    printf '%s\n' ${MC_MERGE_FILES[@]}
    echo  "----------------------------"

    echo  "Remove the above regular files? (y/n)"

    read   REMOVE_MC_MERGE_FILES
    
    if [[ ${REMOVE_MC_MERGE_FILES} == "y"   || ${REMOVE_MC_MERGE_FILES} == "Y"   ||
          ${REMOVE_MC_MERGE_FILES} == "yes" || ${REMOVE_MC_MERGE_FILES} == "Yes" || ${REMOVE_MC_MERGE_FILES} == "YES" ]]; then
        
        rm -f ${MC_MERGE_FILES[@]} ${MC_MERGE_FILELIST}
    else
        printf '%s\n' ${MC_MERGE_FILES[@]} > ${MC_MERGE_FILELIST}
    fi
fi


# Divide into DAQ- and MC-files

echo "Dividing into DAQ- and MC-files..."

set_variable INPUT_MC_FILELIST   ${WORKDIR}/MC.files
set_variable INPUT_DAQ_FILELIST  ${WORKDIR}/DAQ.files

rm -f ${INPUT_MC_FILELIST} ${INPUT_DAQ_FILELIST}
touch ${INPUT_MC_FILELIST} ${INPUT_DAQ_FILELIST}

for INPUT_FILE in ${INPUT_FILES[@]}; do

    if [[ "$(JPrintHeader -f ${INPUT_FILE} -k simul --)" != " 0" ]]; then # MC-file
        set_variable OUTPUT_FILE   ${INPUT_MC_FILELIST}
    else                                                                  # DAQ-files
        set_variable OUTPUT_FILE   ${INPUT_DAQ_FILELIST}
    fi

    if [[ ${INPUT_FILE:e} == "files" ]]; then
        cat  ${INPUT_FILE} >> ${OUTPUT_FILE}
    else
        echo ${INPUT_FILE} >> ${OUTPUT_FILE}
    fi  
done

set_variable N_MC_FILES   $(cat $INPUT_MC_FILELIST  | wc -l)
set_variable N_DAQ_FILES  $(cat $INPUT_DAQ_FILELIST | wc -l)

if (( $N_MC_FILES == 0 )); then
    fatal "No MC input files specified!"
fi


# Initialize job ID file

set_variable JOBID_FILE  ${SCRATCHDIR}/reweighting.jobIDs.txt
rm -f $JOBID_FILE
touch $JOBID_FILE


# Merge MC-files

if (( ${#MC_MERGE_FILES} == 0 )); then

    timer_start

    $JPP_DIR/examples/JAAnet/JSortEvt \
        -f ${INPUT_MC_FILELIST}                                                            \
        -o ${WORKDIR}/\%.merge.root                                                        \
        -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

    timer_stop
    timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

    set_array MC_MERGE_FILES   $(find ${WORKDIR} -maxdepth 1 -name "*.merge.root")
fi


if (( N_DAQ_FILES > 0 )); then

    set_array INPUT_REFERENCE_FILES   $(cat ${INPUT_DAQ_FILELIST})
    set_array INPUT_REWEIGHTING_FILES ${MC_MERGE_FILES[@]}
else

    configure_job \
        ${SCRATCHDIR}/split_events.job\%.sh 1

    exec 3> ${EXEC_FILE}    

    cat <<EOF >&3
#!/bin/zsh

source ${JPP_DIR}/setenv.sh ${JPP_DIR} > /dev/null
EOF

    for MC_MERGE_FILE in ${MC_MERGE_FILES[@]}; do

        set_variable N_EVENTS \
            $(JPrintTree -f ${MC_MERGE_FILE} -@ "type = Evt" -k number_of_entries)
        set_variable N1  $(( N_EVENTS / 2 ))
        set_variable N2  $(( N_EVENTS - N1 ))

        set_variable INPUT_REFERENCE_FILE    ${MC_MERGE_FILE:r}.part1.root
        set_variable INPUT_REWEIGHTING_FILE  ${MC_MERGE_FILE:r}.part2.root
                
        cat <<EOF >&3

timer_start

if [[ ! -f ${INPUT_REFERENCE_FILE} || ! -f ${INPUT_REWEIGHTING_FILE} ]]; then
        
    rm -f ${INPUT_REFERENCE_FILE} ${INPUT_REWEIGHTING_FILE}

    \${JPP_DIR}/examples/JAAnet/JSplitEvt \
        -f ${MC_MERGE_FILE}                                     \
        -o "${INPUT_REFERENCE_FILE} ${INPUT_REWEIGHTING_FILE}"  \
        -d ${DEBUG} --
fi

timer_stop
timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}
    
${SUBMIT_JOB+rm -f ${EXEC_FILE}}
EOF
        
        set_array INPUT_REFERENCE_FILES \
            ${INPUT_REFERENCE_FILES[@]}   ${INPUT_REFERENCE_FILE}
        set_array INPUT_REWEIGHTING_FILES \
            ${INPUT_REWEIGHTING_FILES[@]} ${INPUT_REWEIGHTING_FILE}
    done

    exec 3>&-

    submit_job \
        ${EXEC_FILE} ${(z)${BATCH_PROCESSING:+${QUEUE_NAME} ${SCRATCHDIR}}}
    
    write_jobID ${JOBID_FILE}
    
    reset_job_config
fi


# Process reference files and create histogram comparison steering file

set_variable STEERING_FILE                 ${WORKDIR}/steeringfile.txt
set_variable REFERENCE_POSTFIT_FILE        ${WORKDIR}/reference.postfit.root
set_variable REFERENCE_POSTFIT_FILE_SCALED ${REFERENCE_POSTFIT_FILE:r}.scaled.root

if ( ! reuse_file ${REFERENCE_POSTFIT_FILE} ); then

    rm -f $STEERING_FILE
    touch $STEERING_FILE

    set_array PREREQUISITES $(cat $JOBID_FILE)

    configure_job \
        ${SCRATCHDIR}/${REFERENCE_POSTFIT_FILE:t:r}.job\%.sh 1

    exec 3> ${EXEC_FILE}

    cat <<EOF >&3
#!/bin/zsh

source ${JPP_DIR}/setenv.sh ${JPP_DIR} > /dev/null

timer_start

JAAPostfit    \\
    -f "${INPUT_REFERENCE_FILES[*]}"                                                   \\
    -o  ${REFERENCE_POSTFIT_FILE}                                                      \\
    -a  ${DETX_FILE}                                                                   \\
    -P  ${OSCPROBTABLE}                                                                \\
    -#  ${DEFAULT_OSCPARAMETERS_FILE}                                                  \\
    -@atmospheric="${(k)NULABELS}"                                                     \\
    -%energyRange="${ENERGY_RANGE}"                                                    \\
    -%coszenithRange="${COSTH_RANGE}"                                                  \\
    -%containmentVolume="${CONTAINMENT_VOLUME}"                                        \\
    -%triggeredHitsRange="${N_TRIGGERED_HITS_RANGE}"                                   \\
    -R  ${RECOTYPE} -W                                                                 \\
    -d  ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

JScale1D      \\
    -f ${REFERENCE_POSTFIT_FILE}:.                                                     \\
    -o ${REFERENCE_POSTFIT_FILE_SCALED}                                                \\
    -F ${LIVETIME}                                                                     \\
    -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

mv ${REFERENCE_POSTFIT_FILE_SCALED} ${REFERENCE_POSTFIT_FILE}

timer_stop
timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

set_array NAMES  \$(JPrintName -f ${REFERENCE_POSTFIT_FILE}:.)

for NAME in \${NAMES[@]}; do

    set_variable BINFRAC \
        \$(JPrintResult                                 \
        -f ${REFERENCE_POSTFIT_FILE}:^\${NAME}\$        \
        -F "GetNcells / ((GetNbinsX+2)*(GetNbinsY+2))" \
        -O "%f" --)
        
    if [[ \${NAME} != "META" && \${NAME} != "TObject" ]]; then

        if   (( BINFRAC > 1.0 )); then
            warning "Cannot perform comparison test for histogram \${NAME} with >2 dimensions; skip."
        elif (( BINFRAC < 1.0 )); then
            echo "\${NAME}\$   ${TEST_TYPE1D}   ${TEST_TYPE1D_PARAMETERS}" >> ${STEERING_FILE}
        else
            echo "\${NAME}\$   ${TEST_TYPE2D}   ${TEST_TYPE2D_PARAMETERS}" >> ${STEERING_FILE}
        fi
    fi
done

rm -f ${EXEC_FILE}
EOF

    exec 3>&-    

    submit_job \
        ${EXEC_FILE} ${(z)${BATCH_PROCESSING:+${QUEUE_NAME} ${SCRATCHDIR} $PREREQUISITES[@]}}
    
    write_jobID ${JOBID_FILE}
    
    reset_job_config
fi


# Process MC-files with standard weights

set_variable DEFAULT_POSTFIT_FILE    ${WORKDIR}/default.postfit.root
set_variable DEFAULT_COMPARISON_FILE ${DEFAULT_POSTFIT_FILE:r}.comparison.root

if ( ! reuse_file ${DEFAULT_COMPARISON_FILE} ); then

    echo "Submitting default histogram comparison jobs" 

    configure_job \
        ${SCRATCHDIR}/${DEFAULT_COMPARISON_FILE:t:r}.job\%.sh 1

    exec 3> ${EXEC_FILE}

    cat <<EOF >&3
#!/bin/zsh

source ${JPP_DIR}/setenv.sh ${JPP_DIR} > /dev/null

EOF

    unset DEFAULT_POSTFIT_FILES

    for (( i=1; i<=${#INPUT_REWEIGHTING_FILES}; ++i )); do

        set_variable INPUT_FILE           ${INPUT_REWEIGHTING_FILES[$i]}
        set_variable POSTFIT_FILE         ${INPUT_FILE:r}.postfit.root
        set_variable POSTFIT_FILE_SCALED  ${POSTFIT_FILE:r}.scaled.root

        rm -f ${POSTFIT_FILE} ${COMPARISON_FILE}

        cat <<EOF >&3
timer_start

JAAPostfit         \\
    -f ${INPUT_FILE}                                                                       \\
    -o ${POSTFIT_FILE}                                                                     \\
    -a ${DETX_FILE}                                                                        \\
    -P ${OSCPROBTABLE}                                                                     \\
    -# ${DEFAULT_OSCPARAMETERS_FILE}                                                       \\
    -@atmospheric="${(k)NULABELS}"                                                         \\
    -%energyRange="${ENERGY_RANGE}"                                                        \\
    -%coszenithRange="${COSTH_RANGE}"                                                      \\
    -%containmentVolume="${CONTAINMENT_VOLUME}"                                            \\
    -%triggeredHitsRange="${N_TRIGGERED_HITS_RANGE}"                                       \\
    -R ${RECOTYPE} -W                                                                      \\
    -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE}}

JScale1D           \\
    -f ${POSTFIT_FILE}:.                                                                   \\
    -o ${POSTFIT_FILE_SCALED}                                                              \\
    -F ${LIVETIME}                                                                         \\
    -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

mv ${POSTFIT_FILE_SCALED} ${POSTFIT_FILE}

timer_stop
timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}
EOF

        set_array DEFAULT_POSTFIT_FILES \
            ${DEFAULT_POSTFIT_FILES[@]} ${POSTFIT_FILE}
    done

    cat <<EOF >&3

hadd -v 0 -f ${DEFAULT_POSTFIT_FILE} ${DEFAULT_POSTFIT_FILES[@]}

timer_start
    
JZebraMantis       \\
    -a ${REFERENCE_POSTFIT_FILE}                                                           \\
    -b ${DEFAULT_POSTFIT_FILE}                                                             \\
    -s ${STEERING_FILE}                                                                    \\
    -o ${DEFAULT_COMPARISON_FILE}                                                          \\
    -t ${DEFAULT_COMPARISON_FILE:r}.txt                                                    \\
    -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

timer_stop
timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

rm -f ${EXEC_FILE}
EOF

    exec 3>&-    

    submit_job \
        ${EXEC_FILE} ${(z)${BATCH_PROCESSING:+${QUEUE_NAME} ${SCRATCHDIR} ${REFERENCE_POSTFIT_JOBID}}}

    write_jobID ${JOBID_FILE}

    echo ${EXEC_FILE}

    reset_job_config
fi


# Parse reweighting inputs

unset NUTYPES
unset PARINPUTS

while IFS=$'\t' read TYPES FORMULA PARAMETER_FILE; do

    for TYPE in ${(z)TYPES}; do
        set_array LABELS \
                  ${LABELS[@]} ${NULABELS[$TYPE]}
    done
    
    set_array NUTYPES \
              ${NUTYPES[@]} ${TYPES[@]}

    set_array PARINPUTS \
              ${PARINPUTS[@]} "${LABELS}" "${FORMULA}" "${PARAMETER_FILE}"
    
done < ${REWEIGHTING_INPUTS_FILE}

set_variable PARINPUTS_FILE  ${SCRATCHDIR}/parametersets.${RANDOM}.txt

process_parameters ' ' ${PARINPUTS[@]} > ${PARINPUTS_FILE}


# Compile oscillation parameters files

if [[ ! -z $OSCPARAMETERS_GRID_FILE ]]; then
    
    $JPP_DIR/examples/JOscProb/JWriteOscParametersGrid \
        -@ ${OSCPARAMETERS_GRID_FILE}                  \
        -o ${WORKDIR}/oscillation_parameters.\%.txt \
        -w '%'                                         \
        -d ${DEBUG} --
fi

set_variable OSCPARAMETERS_FILE_LIST   ${WORKDIR}/oscillation_parameters.files

echo ${DEFAULT_OSCPARAMETERS_FILE}          > ${OSCPARAMETERS_FILE_LIST}
ls ${WORKDIR}/oscillation_parameters.*.txt >> ${OSCPARAMETERS_FILE_LIST}


# Process MC-files with redefined weights

set_array PREREQUISITES $(cat $JOBID_FILE)

set_variable META_FILE       ${WORKDIR}/comparisonResults.meta.txt
set_variable JOBID_FILE      ${WORKDIR}/reweighting.jobIDs.txt

rm -f ${META_FILE} ${JOBID_FILE}

integer n=1

while read -u 3 LINE; do

    echo "Submitting reweighting job ${n}"      

    IFS=$'\t' read -r -A PARINPUTS <<< "${LINE}"

    while read -u 4 OSCPARAMETERS_FILE; do

        set_variable REWEIGHTED_POSTFIT_FILE      ${WORKDIR}/reweighting.${n}.postfit.root
        set_variable REWEIGHTED_COMPARISON_FILE   ${REWEIGHTED_POSTFIT_FILE:r}.comparison.root
        
        configure_job \
            ${SCRATCHDIR}/reweighting.job\%.sh ${JOB_SIZE}

        if (( ${+START_JOB} )); then

            exec 5> ${EXEC_FILE}
            
            cat <<EOF >&5
#!/bin/zsh

source ${JPP_DIR}/setenv.sh ${JPP_DIR} > /dev/null
EOF
        fi

        for (( j=1; j<=${#INPUT_REWEIGHTING_FILES}; ++j )); do

            set_variable INPUT_FILE           ${INPUT_REWEIGHTING_FILES[$j]}
            set_variable REWEIGHTED_FILE      ${INPUT_FILE:r}.reweighting.${n}.root
            set_variable POSTFIT_FILE         ${REWEIGHTED_FILE:r}.postfit.root
            set_variable POSTFIT_FILE_SCALED  ${POSTFIT_FILE:r}.scaled.root

            set_array POSTFIT_FILES \
                      ${POSTFIT_FILES[@]} ${POSTFIT_FILE}
            
            cat <<EOF >&5

set_array PRIMARIES \\
    \$(JPrintHeader -f ${INPUT_FILE} -k primary -- | cut -d'=' -f2)

set_array PRIMARIES  \\
    \${PRIMARIES[@]} \\
    \$(JPrintHeader -f ${INPUT_FILE} -k flux --    | cut -d' ' -f3)

unset DO_REWEIGHTING

for PRIMARY in \${PRIMARIES[@]}; do
    if [[ "${NUTYPES[@]}" =~ "\${PRIMARY}" ]]; then
        set_variable DO_REWEIGHTING
        break
    fi
done

if (( \${+DO_REWEIGHTING} )); then

    timer_start

    JEvtReweightGSeaGen \\
        -f  ${INPUT_FILE}                                                                      \\
        -o  ${REWEIGHTED_FILE}                                                                 \\
        -P  ${OSCPROBTABLE}                                                                    \\
        -@  ${OSCPARAMETERS_FILE}                                                              \\
$(printf '        -#%s \\\n' ${PARINPUTS[@]})
        -d  ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

     timer_stop
     timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

     timer_start

    JAAPostfit          \\
        -f ${REWEIGHTED_FILE}                                                                  \\
        -o ${POSTFIT_FILE}                                                                     \\
        -a ${DETX_FILE}                                                                        \\
        -P ${OSCPROBTABLE}                                                                     \\
        -%energyRange="${ENERGY_RANGE}"                                                        \\
        -%coszenithRange="${COSTH_RANGE}"                                                      \\
        -%containmentVolume="${CONTAINMENT_VOLUME}"                                            \\
        -%triggeredHitsRange="${N_TRIGGERED_HITS_RANGE}"                                       \\
        -R ${RECOTYPE} -W                                                                      \\
        -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

    JScale1D           \\
        -f ${POSTFIT_FILE}:.                                                                   \\
        -o ${POSTFIT_FILE_SCALED}                                                              \\
        -F ${LIVETIME}                                                                         \\
        -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

    mv ${POSTFIT_FILE_SCALED} ${POSTFIT_FILE}

    timer_stop
    timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

else # This file does not correspond to any of the given primaries

    ln -fv ${INPUT_FILE}                  ${REWEIGHTED_FILE}
    ln -fv ${INPUT_FILE:r}.postfit.root   ${POSTFIT_FILE}
fi

rm -f ${REWEIGHTED_FILE}
EOF
        done

        cat <<EOF >&5

hadd -v 0 -f ${REWEIGHTED_POSTFIT_FILE} ${POSTFIT_FILES[@]}

timer_start

JZebraMantis        \\
    -a ${REFERENCE_POSTFIT_FILE}                                                           \\
    -b ${REWEIGHTED_POSTFIT_FILE}                                                          \\
    -s ${STEERING_FILE}                                                                    \\
    -o ${REWEIGHTED_COMPARISON_FILE}                                                       \\
    -t ${REWEIGHTED_COMPARISON_FILE:r}.txt                                                 \\
    -d ${DEBUG} --! ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

timer_stop
timer_print ${BATCH_LOGGING:+&>> ${LOG_FILE} 2>&1}

${SUBMIT_JOB+#rm -f ${EXEC_FILE}}
EOF

        if (( ${+SUBMIT_JOB} )); then

            exec 5>&-

            submit_job \
                ${EXEC_FILE} ${(z)${BATCH_PROCESSING:+${QUEUE_NAME} ${SCRATCHDIR} ${PREREQUISITES[@]}}}

            write_jobID ${JOBID_FILE}

            unset POSTFIT_FILES
        fi

        echo "${REWEIGHTED_COMPARISON_FILE:r}.txt\t${OSCPARAMETERS_FILE}\t${PARINPUTS[*]}" >> ${META_FILE}

        (( ++n ))

    done 4< ${OSCPARAMETERS_FILE_LIST}

done 3< ${PARINPUTS_FILE}

rm -f ${PARINPUTS_FILE}

reset_job_config

set_variable IFS                                  ${IFS0}