JAcceptanceTest.sh

Go to the documentation of this file.

#!/bin/zsh

version=1.0
script=${0##*/}


if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR

if (( $# < 3 )); then
     fatal "Not enough arguments."
fi

set_variable    DAQ_FILE            $argv[1]
set_variable    DETECTOR_FILE       $argv[2]
set_variable    OUTPUT_DIR          $argv[3]

set_variable    OUTPUT_JC_TOT       ${OUTPUT_DIR}/$(basename $DAQ_FILE .root)_JC_TOT.root
set_variable    OUTPUT_JMERGE_TOT   ${OUTPUT_DIR}/$(basename $DAQ_FILE .root)_JMerge_TOT.root
set_variable    OUTPUT_JFIT_TOT     ${OUTPUT_DIR}/$(basename $DAQ_FILE .root)_JFit_TOT.root
set_variable    PMT_PARAMETERS_FILE ${OUTPUT_DIR}/$(basename $DAQ_FILE .root)_TOT.txt
set_variable    OUTPUT_JDA          ${OUTPUT_DIR}/$(basename $DAQ_FILE .root)_JDA.root


set_variable    SELECTOR            JDAQTimeslice
set_variable    NUMBER_OF_PMTS      31

JCalibrateToT \
    -a ${DETECTOR_FILE} \
    -C ${SELECTOR} \
    -O filter \
    -f ${DAQ_FILE} \
    -o ${OUTPUT_JC_TOT} --!

JMergeCalibrateToT \
    -f ${OUTPUT_JC_TOT} \
    -o ${OUTPUT_JMERGE_TOT} --!

JFitToT \
    -P ${PMT_PARAMETERS_FILE} \
    -a ${DETECTOR_FILE} \
    -f ${OUTPUT_JMERGE_TOT} \
    -o ${OUTPUT_JFIT_TOT} \
    -x "0.0 -1.0" \
    -w --!

${JPP_DIR}/examples/JDOMProduction/JDomAnalyser \
          -f ${DAQ_FILE} \
          -o ${OUTPUT_JDA} \
          --!

#---- loop over DOMs and for each print the gains (for copying into DIA interface)

eval `JPrintDetector -a $DETECTOR_FILE -O SUMMARY`

attach getModule -a $DETECTOR_FILE

for STRING in $STRINGS[*]; do
    for (( FLOOR = $FIRST_FLOOR; $FLOOR <= $LAST_FLOOR; FLOOR += 1 )); do

        GAINS=()
        RATES=()
        
        print -u $FD_O "$STRING $FLOOR"
        read MODULE <& $FD_I

        for (( CHAN = 0; $CHAN < $NUMBER_OF_PMTS; CHAN += 1 )); do
            
            GAINS+=(`awk -v mod=$MODULE -v chan=$CHAN '($1=="PMT=" && $2==mod && $3==chan){print $5}' ${PMT_PARAMETERS_FILE}`)
            RATES+=(`JPrintResult -f ${OUTPUT_JDA}:rate_${MODULE}.${CHAN}$ -F "GetMean"`)

            JPlot1D \
                -f ${OUTPUT_JFIT_TOT}:${MODULE}\.${CHAN}\.1ToT \
                -Y \
                -y "1.e-7 1.5e-1" \
                -\> "ToT" \
                -T "${MODULE}: ${CHAN}" \
                -o ${OUTPUT_DIR}/gain_${(l(2)(0))CHAN}.gif -B

            JPlot1D \
                -f ${OUTPUT_JDA}:rate_${MODULE}.${CHAN}$ \
                -Y \
                -y "1.e-7 1e5" \
                -X \
                -\> "Rate [Hz]" \
                -T "${MODULE}: ${CHAN}" \
                -o ${OUTPUT_DIR}/rate_${(l(2)(0))CHAN}.gif -B

        done
        
        JSON="{\n\"module\":$MODULE,\n"

        JSON+="\"gains\":["
        JSON+=$(IFS=, ; echo "${GAINS[*]}")
        JSON+="],\n"

        JSON+="\"rates\":["
        JSON+=$(IFS=, ; echo "${RATES[*]}")
        JSON+="]\n}"

        echo -e ${JSON}
        
        montage \
            -tile 6x6 \
            -geometry +0+0 \
            ${OUTPUT_DIR}/gain*.gif \
            ${OUTPUT_DIR}/${MODULE}_gain.gif

        montage \
            -tile 6x6 \
            -geometry +0+0 \
            ${OUTPUT_DIR}/rate*.gif \
            ${OUTPUT_DIR}/${MODULE}_rate.gif
    done
done

rm -f ${OUTPUT_DIR}/gain*.gif
rm -f ${OUTPUT_DIR}/rate*.gif

detach