JRandomEventRunByRun.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author zaly
#
version=1.0
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#    Script to jointly run JRandomTimesliceWriter and JTriggerProcessor in run-by-run mode.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

# set environment for Jpp
source $JPP_DIR/setenv.sh $JPP_DIR


set_variable  DEBUG              ${RANDOMEVENT_DEBUG:-1}
set_variable  WORKDIR            ./
set_variable  PIPE               $WORKDIR/pipe.dat
set_variable  OUTPUT_FILE        $WORKDIR/trigger_processor.root
set_variable  DETECTOR           $JPP_DATA/km3net_reference.detx
set_variable  TRIGGER            $JPP_DATA/trigger_parameters_arca.txt
set_variable  PMT_FILE           $JPP_DATA/PMT_parameters.txt
set_variable  BACKGROUND_HZ      ${RANDOMEVENT_BACKGROUND_HZ:-${BACKGROUND_HZ:-0.0 600 60 6 0.6}}
set_variable  NUMBER_OF_SLICES   ${RANDOMEVENT_SLICES:-10}
set_variable  RECYCLING          ${RANDOMEVENT_RECYCLING:-"0 0"}
set_variable  JDAQ_TIMESLICE     JDAQTimesliceL0
set_variable  SEED               ${RANDOMEVENT_SEED:-0}


if ( do_usage $* ); then
    usage "$script [daq file [detector file [pipe [output file [trigger file [PMT parameters file]]]]]]"
fi

case $# in
    6)  set_variable PMT_FILE     $6;&
    5)  set_variable TRIGGER      $5;&
    4)  set_variable OUTPUT_FILE  $4;&
    3)  set_variable PIPE         $3;&
    2)  set_variable DETECTOR     $2;&
    1)  set_variable DAQ_FILE     $1;;
esac


print_variable     DETECTOR TRIGGER OUTPUT_FILE BACKGROUND_HZ PMT_FILE
check_input_file   $DETECTOR $TRIGGER $PMT_FILE
check_output_file  $OUTPUT_FILE

#################################################################################################
#
# The sampler values correspond to N_on N_off, respectively (note that sampler calls JSampler),
# where:
# N_on   =  number of time slices to read;
# N_off  =  number of time slices to skip.
#
# The sampler option works as follows.
# It will
# read -on average- N_on  consecutive time slices and  
# skip -on average- N_off time slices
# modulo the number of time slices in the file.
#
# The larger N_on, the faster the reading, because this reduces the random accesses 
# of the data taking file to pick up a next time slice.
# The smaller N_off, the less time slices are skipped.
# So, N_on = 0 guarantees that all time slices are sampled.
# Note that if the number of time slices to be produced is small, then too small a value of N_off
# could create a bias because only the first time slices of the data taking file are then sampled.
#################################################################################################

RUNBYRUN="file=$DAQ_FILE; sampler=1 1000; range_Hz=1e3 1e5"

rm -f  $PIPE
mkfifo $PIPE

if [[ -p $PIPE ]]; then

    timer_start
    
    JRandomTimesliceWriter \
        -a ${DETECTOR}                \
        -o ${PIPE}                    \
        -n ${NUMBER_OF_SLICES}        \
        -P ${PMT_FILE}                \
        -d ${DEBUG}                   \
        -S ${SEED}                    \
        -B "$BACKGROUND_HZ"           \
        -N "$RECYCLING"               \
        -r "${RUNBYRUN}"              \
        --! &

    JTriggerProcessor \
        -a ${DETECTOR}                \
        -f ${PIPE}                    \
        -@ ${TRIGGER}                 \
        -C ${JDAQ_TIMESLICE}          \
        -o ${OUTPUT_FILE}             \
        -d ${DEBUG}                   \
        --! 
        
    rm -f $PIPE
     
    timer_stop
    timer_print

    JPrintTree \
        -f ${OUTPUT_FILE}

else

    fatal "Error opening $PIPE."
fi

JTriggerMonitor -f ${OUTPUT_FILE} -o  ${OUTPUT_FILE}.monitor.root --!