JTunePMTThreshold.sh

Go to the documentation of this file.

#!/bin/zsh
#
# \author mdejong
#
script=${0##*/}

# ------------------------------------------------------------------------------------------
#
#                         Script to run tune PMT thresholds.
#
# ------------------------------------------------------------------------------------------

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi
source $JPP_DIR/setenv.sh $JPP_DIR

set_variable:  JDAQ_TIMESLICE    CALIBRATION_DAQ_TIMESLICE     JDAQTimesliceL0
set_variable:  WORKDIR           CALIBRATION_WORKDIR           ./
set_variable:  TOT_RANGE         CALIBRATION_TOT_RANGE         "0 8"
set_variable:  FRACTION          CALIBRATION_FRACTION          0.5
set_variable:  DEBUG             CALIBRATION_DEBUG             2

if do_usage $*; then
    usage "$script <detector file> (input file)+ <PMT threshold file (JSon format)>"\
          "\nAuxiliary script to tune PMT thresholds."
fi

if (( $# < 3 )); then
    fatal "Wrong number of arguments."
fi

set_variable  DETECTOR      $argv[1]
set_array     INPUT_FILES   $argv[2,-2]
set_variable  JSON_FILE     $argv[-1]

JEditDetector \
    -a $DETECTOR                               \
    -P "-1 -1 set HIGH_RATE_VETO_DISABLE"      \
    -o $WORKDIR/detector.datx                  \
    -d 1

set_variable  DETECTOR      $WORKDIR/detector.datx

OUTPUT_FILES=()

for INPUT_FILE in $INPUT_FILES[*]; do

    JPrintDAQHeader -f $INPUT_FILE -d 0 | read DETECTOR_ID RUN FRAME_INDEX TIMESLICE_START

    set_variable  OUTPUT_FILE  $WORKDIR/KM3NeT_${(l:8::0::0:)DETECTOR_ID}_${(l:8::0::0:)RUN}_monitor.root

    if [[ ! -f $OUTPUT_FILE ]]; then

        echo Processing $INPUT_FILE

        JCalibrateToT \
            -a $DETECTOR               \
            -f $INPUT_FILE             \
            -o $OUTPUT_FILE            \
            -C $JDAQ_TIMESLICE         \
            -d $DEBUG
    fi

    OUTPUT_FILES+=($OUTPUT_FILE)

done

JTunePMTThreshold \
    -f "$OUTPUT_FILES"      \
    -x "$TOT_RANGE"         \
    -t  $FRACTION           \
    -o  $JSON_FILE          \
    -d  $DEBUG --!