archive-put-pmt.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable:  DEBUG           ARCHIVE_DEBUG          2
set_variable:  WORKDIR         ARCHIVE_WORKDIR        ${TMPDIR:-/tmp}/
set_variable   TYPE            pmt

if do_usage $*; then
    usage "$script <source directory> <detector identifier> <suffix> <archive> <version>"\
          "\nAuxiliary script to download online detector files from database and to store these in archive."\
          "\nNote that the given suffix and version should match with that in the file names."
fi

if (( $# == 5 )); then
    set_variable  DIR             $argv[1]
    set_variable  DETECTOR_ID     $argv[2]
    set_variable  SUFFIX          $argv[3]
    set_variable  ARCHIVE         $argv[4]
    set_variable  VERSION         $argv[5]
else
    fatal "Wrong number of arguments."
fi

set_variable  DETECTOR_ID     $(getDetector -D $DETECTOR_ID -O int)
set_variable  PREFIX          KM3NeT_${(l:8::0::0:)DETECTOR_ID}
set_variable  SUFFIX          ${VERSION}_${SUFFIX}

typeset -A DATABASE
typeset -T BUFFER  ARRAY  _

for FILE_NAME in `ls ${DIR}/${PREFIX}_*\.${SUFFIX}.txt`; do

    BUFFER=${${FILE_NAME:t}%%\.*}

    let "ID  = $ARRAY[2]"
    let "RUN = $ARRAY[3]"

    DATABASE[$RUN]=$FILE_NAME
done

if (( ${#DATABASE} == 0 )); then
    fatal "No input files at ${DIR}/${PREFIX}_*\.${SUFFIX}.txt."
fi

MINRUN=`echo ${(k)DATABASE} | tr ' ' '\n' | sort -g | head -n 1`
MAXRUN=`echo ${(k)DATABASE} | tr ' ' '\n' | sort -g | tail -n 1`

for (( i0 = $MINRUN; $i0 <= $MAXRUN; )); do

    if (( ${+DATABASE[$i0]} == 1 )); then

        notice "Run $i0 $DATABASE[$i0]"

        egrep -v "^#" $DATABASE[$i0] > $WORKDIR/i0.txt

        for (( i1 = $i0 + 1; $i1 <= $MAXRUN; i1 += 1 )); do

            if (( ${+DATABASE[$i1]} == 0 )); then
                continue
            fi

            notice "Run $i1 $DATABASE[$i1]"

            egrep -v "^#" $DATABASE[$i1] > $WORKDIR/i1.txt

            diff $WORKDIR/i0.txt $WORKDIR/i1.txt >& /dev/null
        
            if (( $? != 0 )); then
                break
            fi
        done

        putFile.sh  ${DATABASE[$i0]}  $ARCHIVE  $DETECTOR_ID  $i0  $(($i1 - 1))  $TYPE  $VERSION

        let "i0 = $i1"
    else

        let "i0 = $i0 + 1"
    fi
done

rm -f $WORKDIR/i{0,1}.txt