JCheckK40.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

set_variable:  DEBUG              CALIBRATION_DEBUG          1
set_variable:  WORKDIR            CALIBRATION_WORKDIR        `pwd`
set_variable:  DAQ_TIMESLICE      CALIBRATION_TIMESLICE      JDAQTimesliceL1
set_variable+  DATABASE_OPTION    CALIBRATION_USEPMTID       -U
set_variable:  FORMAT             GRAPHICS_FORMAT            gif
set_variable+  BATCH              GRAPHICS_BATCH             -B

if do_usage $*; then
    usage "$script <detector file> <input file> <input file> <input file>"\
          "\nThe 1st and 3rd input file should correspond to a data taking run in which the HV settings are complete (e.g. \"vendor\" or \"tuned\")."\
          "\nThe 2nd input file should correspond to a run with hybrid HV settings."\
          "\nIn this, half of the PMTs should have the same HV settings as either the 1st or 3rd input file."
fi

if (( $# == 4 )); then
    set_variable  DETECTOR      $argv[1]
    set_array     INPUT_FILES   $argv[2,-1]
else
    fatal "Wrong number of arguments."
fi

    
RUNS=()

for INPUT_FILE in $INPUT_FILES[*]; do

    JPrintDAQHeader -f $INPUT_FILE  |  read  DETECTOR_ID  RUN  FRAME_INDEX  UTC
        
    RUNS+=($RUN)

    # Background option

    if (( `JPrintTree -f $INPUT_FILE -@ "type = JDAQSummaryslice" -k number_of_entries` > 0 )); then
        set_variable OPTION  rates
    else
        set_variable OPTION  counts
    fi

    set_variable  OUTPUT_FILE              $WORKDIR/monitor_${RUN}.root

    if [[ ! -f $OUTPUT_FILE ]]; then

        JCalibrateK40 \
            -f $INPUT_FILE                               \
            -C $DAQ_TIMESLICE                            \
            -a $DETECTOR                                 \
            -o $OUTPUT_FILE                              \
            -b $OPTION                                   \
            -d $DEBUG
    fi
done

#
# Monitor pair of data taking runs.
#
# \param  1       1st run
# \param  2       2nd run
#
function monitor()
{
    $JPP_DIR/examples/JCalibrate/JCheckK40 \
        -a  $DETECTOR                                                          \
        -f "$WORKDIR/monitor_${1}.root  $WORKDIR/monitor_${2}.root"            \
        -o  $WORKDIR/monitor\[${1}-${2}\].root                                 \
        $DATABASE_OPTION                                                       \
        -d  $DEBUG --!
}

# Monitor

monitor  $RUNS[1]   $RUNS[2]
monitor  $RUNS[2]   $RUNS[3]

if (( 1 )); then

    eval `JPrintDetector -a $DETECTOR -O SUMMARY`

    kill_child_processes_at_exit

    attach getModule -a $DETECTOR

    typeset -Z 4 STRING
    typeset -Z 2 FLOOR

    for STRING in $STRINGS[*]; do
        for (( FLOOR = 1; $FLOOR <= 18; ++FLOOR )); do

            sput $STRING $FLOOR
            sget  MODULE
    
            JPlot1D \
                -f $WORKDIR/monitor\[${RUNS[1]}-${RUNS[2]}\].root:${MODULE}    \
                -f $WORKDIR/monitor\[${RUNS[2]}-${RUNS[3]}\].root:${MODULE}    \
                -y "-10.0 +10.0"                                               \
                -\> "PMT"                                                      \
                -\^ "#Deltat [ns]"                                             \
                -T "${STRING}.${FLOOR} ($MODULE)"                              \
                -L TL                                                          \
                -o ${MODULE}-${RUNS[1]}-${RUNS[2]}-${RUNS[3]}.${FORMAT}        $BATCH
        done
    done

    detach
fi

---

Generated by   1.8.5