plot-acoustics-fit.sh

Go to the documentation of this file.

#!/bin/zsh
script=${0##*/}

if [ -z $JPP_DIR ]; then
    echo "Variable JPP_DIR undefined."
    exit
fi

source $JPP_DIR/setenv.sh $JPP_DIR >& /dev/null

zmodload zsh/mathfunc

set_variable   DEBUG       2
set_variable   WORKDIR     ${TMPDIR:-/tmp}/
set_variable   STAGE       \*
set_variable:  PRECISION   ACOUSTICS_PRECISION    0.1
set_variable:  FORMAT      GRAPHICS_FORMAT        gif
set_variable+  BATCH       GRAPHICS_BATCH         -B

if do_usage $*; then
    usage "$script <directory> [stage]"\
          "\nInput directory corresponds to location of stage files of a pre-calibration procedure."
fi

case $# in
    2) set_variable  STAGE  $2;&
    1) set_variable  DIR    $1;;
    *) fatal "Wrong number of arguments."
esac

for INPUT_FILE in `eval ls -rt $DIR/stage-${STAGE}.log`; do

    grep "\(chi2\[.\]\|gradient\|string:\)" $INPUT_FILE  >  $WORKDIR/stage.txt

    awk 'BEGIN { YMAX = 0.0; YMIN = 1.0e10 } END { printf "%9.5f %9.5f", YMIN, YMAX} /chi2/ { if ($3 < 1.0e10) { if ($3 < YMIN) { YMIN = $3}; if ($3 > YMAX) { YMAX = $3 }}}'  $WORKDIR/stage.txt  |  read YMIN YMAX

    let "Y    = $YMAX - $YMIN"
    let "YMAX = floor(($YMAX + 0.1 * ($Y)) / $PRECISION + 1.0) * $PRECISION"
    let "YMIN = floor(($YMIN - 0.1 * ($Y)) / $PRECISION - 0.0) * $PRECISION"

    if (( $YMIN < 0.0 )); then
        let "YMIN = 0.0"
    fi

    OUTPUT_FILES=()

    awk '/chi2\[.\]/ { printf "%5d %9.5f\n", NR, $3 }'                        $WORKDIR/stage.txt  >  $WORKDIR/g1.txt

    JGraph \
        -f $WORKDIR/g1.txt                       \
        -o $WORKDIR/g1.root                      \
        -T $TITLE

    OUTPUT_FILES+=$WORKDIR/g1.root

    awk \
        -v YMIN=$YMIN \
        -v YMAX=$YMAX \
        '/gradient/  { printf "%5d %9.5f %5d %9.5f\n", NR, YMIN, NR, YMAX }'  $WORKDIR/stage.txt  >  $WORKDIR/L1.txt  

    JLine \
        -p $WORKDIR/L1.txt                       \
        -o $WORKDIR/L1.root                      \
        -@ "width = 1"                           \
        -@ "style = 2"                           

    OUTPUT_FILES+=$WORKDIR/L1.root

    if [[ $INPUT_FILE == *b.log ]] || [[ $INPUT_FILE == *B.log ]]; then

        awk \
            -v YMIN=$YMIN \
            -v YMAX=$YMAX \
            'BEGIN { NL = 1 } /string:/  { printf "%5d %9.5f %04d\n", NL, YMAX * 0.97, $2;     NL = NR + 1 }'  $WORKDIR/stage.txt  >  $WORKDIR/T1.txt

        awk \
            -v YMIN=$YMIN \
            -v YMAX=$YMAX \
            'BEGIN { NL = 1 } /string:/  { printf "%5d %9.5f %5d %9.5f\n", NL, YMIN, NL, YMAX; NL = NR + 1 }'  $WORKDIR/stage.txt  >  $WORKDIR/L2.txt  

        JText \
            -p $WORKDIR/T1.txt                       \
            -o $WORKDIR/T1.root                      \
            -@ "align = 12"                          \
            -@ "size  = 15"

        JLine \
            -p $WORKDIR/L2.txt                       \
            -o $WORKDIR/L2.root                      \
            -@ "width = 1"                           \
            -@ "style = 1"                           

        OUTPUT_FILES+=$WORKDIR/T1.root
        OUTPUT_FILES+=$WORKDIR/L2.root  
    fi
    
    JPlot1D \
        -w 1200x600                              \
        -f${^OUTPUT_FILES}":.*"                  \
        -\> "step"                               \
        -\^ "#chi^{2}/NDF"                       \
        -y "$YMIN $YMAX"                         \
        -N "X 505"                               \
        -G Y                                     \
        -S 0.5                                   \
        -T "${${INPUT_FILE:t}:r}"                \
        -o  ${${INPUT_FILE:t}:r}.$FORMAT         $BATCH

    rm -f $WORKDIR/stage.txt $WORKDIR/{g,L,M,T}{1,2}.{txt,root}
done